将ASP的Debug变得简单的两个函数

<%
'---------------------------------------------------------------------------
' 程序作用:打印request.form输入的所有值
'---------------------------------------------------------------------------
Response.Write FormData()
function FormData()
Dim llngMaxFieldIndex
Dim llngFieldIndex
Dim llngMaxValueIndex
Dim llngValueIndex
Dim lstrDebug
' Count Form
llngMaxFieldIndex = Request.Form.Count

' Let user know if Form Do Not exist
if llngMaxFieldIndex = 0 Then
FormData = "Form data is empty."
Exit function
End if

' Begin building a list of all Form
lstrDebug = "<OL>"

' Loop through Each Form
For llngFieldIndex = 1 To llngMaxFieldIndex
lstrDebug = lstrDebug & "<LI>" & Server.HTMLEncode(Request.Form.Key(llngFieldIndex))

' Count the values
llngMaxValueIndex = Request.Form(llngFieldIndex).Count

' if the Field doesn't have multiple values ...
if llngMaxValueIndex = 1 Then
lstrDebug = lstrDebug & " = "
lstrDebug = lstrDebug & Server.HTMLEncode(Request.Form.Item(llngFieldIndex))
' Else Loop through Each value
Else
lstrDebug = lstrDebug & "<OL>"
For llngValueIndex = 1 To llngMaxValueIndex
lstrDebug = lstrDebug & "<LI>"
lstrDebug = lstrDebug & Server.HTMLEncode(Request.Form(llngFieldIndex)(llngValueIndex))
lstrDebug = lstrDebug & "</LI>"
Next
lstrDebug = lstrDebug & "</OL>"
End if
lstrDebug = lstrDebug & "</LI>"
Next
lstrDebug = lstrDebug & "</OL>"
' Return the data
FormData = lstrDebug

End function

%>

<%
'-------------------------------------------------------------------------
' 函数功能：输出所有输入request.querystring值，用于调试！
'-------------------------------------------------------------------------

Response.Write QueryStringData()
function QueryStringData()
Dim llngMaxFieldIndex
Dim llngFieldIndex
Dim llngMaxValueIndex
Dim llngValueIndex
Dim lstrDebug
' Count QueryString
llngMaxFieldIndex = Request.QueryString.Count

' Let user know if QueryString Do Not exist
if llngMaxFieldIndex = 0 Then
QueryStringData = "QueryString data is empty."
Exit function
End if

' Begin building a list of all QueryString
lstrDebug = "<OL>"

' Loop through Each QueryString
For llngFieldIndex = 1 To llngMaxFieldIndex
lstrDebug = lstrDebug & "<LI>" & Server.HTMLEncode(Request.QueryString.Key(llngFieldIndex))

' Count the values
llngMaxValueIndex = Request.QueryString(llngFieldIndex).Count

' if the Field doesn't have multiple values ...
if llngMaxValueIndex = 1 Then
lstrDebug = lstrDebug & " = "
lstrDebug = lstrDebug & Server.HTMLEncode(Request.QueryString.Item(llngFieldIndex))
' Else Loop through Each value
Else
lstrDebug = lstrDebug & "<OL>"
For llngValueIndex = 1 To llngMaxValueIndex
lstrDebug = lstrDebug & "<LI>"
lstrDebug = lstrDebug & Server.HTMLEncode(Request.QueryString(llngFieldIndex)(llngValueIndex))
lstrDebug = lstrDebug & "</LI>"
Next
lstrDebug = lstrDebug & "</OL>"
End if
lstrDebug = lstrDebug & "</LI>"
Next
lstrDebug = lstrDebug & "</OL>"
' Return the data
QueryStringData = lstrDebug

End function

%>